注册 登陆
浏览模式: 标准 | 列表 分类: DELPHI

DbGrid适应宽度

Delphi代码
  1. uses  
  2. Math;   
  3.   
  4. function DBGridRecordSize(mColumn: TColumn): Boolean;   
  5. { 返回记录数据网格列显示最大宽度是否成功 }  
  6. begin  
  7. Result := False;   
  8. if not Assigned(mColumn.Field) then Exit;   
  9. mColumn.Field.Tag := Max(mColumn.Field.Tag,   
  10.     TDBGrid(mColumn.Grid).Canvas.TextWidth(mColumn.Field.DisplayText));   
  11. Result := True;   
  12. end{ DBGridRecordSize }  
  13.   
  14. function DBGridAutoSize(mDBGrid: TDBGrid; mOffset: Integer = 5): Boolean;   
  15. { 返回数据网格自动适应宽度是否成功 }  
  16. var  
  17. I: Integer;   
  18. begin  
  19. Result := False;   
  20. if not Assigned(mDBGrid) then Exit;   
  21. if not Assigned(mDBGrid.DataSource) then Exit;   
  22. if not Assigned(mDBGrid.DataSource.DataSet) then Exit;   
  23. if not mDBGrid.DataSource.DataSet.Active then Exit;   
  24. for I := 0 to mDBGrid.Columns.Count - 1 do begin  
  25.     if not mDBGrid.Columns[I].Visible then Continue;   
  26.     if Assigned(mDBGrid.Columns[I].Field) then  
  27.       mDBGrid.Columns[I].Width := Max(mDBGrid.Columns[I].Field.Tag,   
  28.         mDBGrid.Canvas.TextWidth(mDBGrid.Columns[I].Title.Caption)) + mOffset   
  29.     else mDBGrid.Columns[I].Width :=   
  30.       mDBGrid.Canvas.TextWidth(mDBGrid.Columns[I].Title.Caption) + mOffset;   
  31.     mDBGrid.Refresh;   
  32. end;   
  33. Result := True;   
  34. end{ DBGridAutoSize }  
  35. ///////End Source   
  36.   
  37. ///////Begin Demo   
  38. procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;   
  39. DataCol: Integer; Column: TColumn; State: TGridDrawState);   
  40. begin  
  41. DBGridRecordSize(Column);   
  42. end;   
  43.   
  44. procedure TForm1.Button1Click(Sender: TObject);   
  45. begin  
  46. DBGridAutoSize(DBGrid1);   
  47. end;  

在delphi中实现网页的自动输入

如果webbrowser由你创建
如果网页内容可知

用263举个例子

procedure   TForm1.FormCreate(Sender:   TObject);
begin
    b   :=   false;
    webbrowser1.Navigate('http://www.263.net');
end;

procedure   TForm1.WebBrowser1DocumentComplete(Sender:   TObject;
    const   pDisp:   IDispatch;   var   URL:   OleVariant);
begin
    b   :=   True;
end;

procedure   TForm1.Button1Click(Sender:   TObject);
var
    o   :   Olevariant;
begin
    if   b   then
    begin
        //   263页面上的"用户名"输入的input的name=user,密码输入的input的name=pass
        //   所以直接用名字取
        //   也可以用webbroser1.oleobject.document.all.tags('input',第几个input);
        //   其它属性见msdn
        o   :=   webbrowser1.OleObject.document.all.item('user',0);
        o.value   :=   '12345';
        o   :=   webbrowser1.oleobject.document.all.item('pass',0);
        o.value   :=   '54321';
        o   :=   webbrowser1.oleobject.document.all.item('login',0);
        o.submit;
        //   登陆成功
    end
end;

 

WebBrowser js脚本错误

Delphi代码
  1. WebBrowser1.Silent   :=True;    

delphi 预编译 实例

Delphi代码
  1. function WriteDB(PageUrl,PageDegest,CurrentTime,PageEncode: string;PageRank,PageLength: integer): boolean;   
  2. var Writer: TADOQuery;   
  3. begin  
  4.   Writer:= TADOQuery.Create(nil);   
  5.   try  
  6.   Result:= False;//提示:这和C不同,不会立即返回.   
  7.   Writer.SQL.Clear;   
  8.   Writer.SQL.Add('insert into so211_server(PageUrl,PageDegest,CurrentTime,PageEncode,PageRank,PageLength) values(:para1,:para2,:para3,:para4,:para5,:para6)');   
  9.   Writer.Parameters.ParamByName('para1').Value:=PageUrl;   
  10.   Writer.Parameters.ParamByName('para2').Value:=PageDegest;   
  11.   Writer.Parameters.ParamByName('para3').Value:=CurrentTime;   
  12.   Writer.Parameters.ParamByName('para4').Value:=PageEncode;   
  13.   Writer.Parameters.ParamByName('para5').Value:=PageRank;   
  14.   Writer.Parameters.ParamByName('para6').Value:=PageLength;   
  15.   Writer.ExecSQL;   
  16.   Result:=true;   
  17.   finally  
  18.     Writer.Close;   
  19.     Writer.Free;   
  20.   end;   
  21. end;  

线程杂谈

前言 
由于项目的关系,所以和线程的接触颇多,常常遇到问题,常常看TThread的代码,又常常想一些办法来解决遇到的问题,所以就有了这篇文章。 

正文 
我们常有工作线程和主线程之分,工作线程负责作一些后台操作,比如接收邮件;主线程负责界面上的一些显示。工作线程的好处在某些时候是不言而喻的,你的主界面可以响应任何操作,而背后的线程却在默默地工作。 
VCL中,工作线程执行在Execute方法中,你必须从TThread继承一个类并覆盖Execute方法,在这个方法中,所有代码都是在另一个线程中执行的,除此之外,你的线程类的其他方法都在主线程执行,包括构造方法,析构方法,Resume等,很多人常常忽略了这一点。  …………

» 阅读全文

delphi时间转换为GMT格式

//时间转换为GMT格式
function DateTimeToGMT(Const DateTime: TDateTime): String;
begin


  Result := FormatDateTime(’ddd, dd mmm yyyy hh:mm:ss’,DateTime);


  Result := StringReplace(Result, ‘一月’, ‘Jan’, [rfReplaceAll]);


  Result := StringReplace(Result, ‘二月’, ‘Feb’, [rfReplaceAll]);


  Result := StringReplace(Result, ‘三月’, ‘Mar’, [rfReplaceAll]);


  Result := StringReplace(Result, ‘四月’, ‘Apr’, [rfReplaceAll]);


  Result := StringReplace(Result, ‘五月’, ‘May’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘六月’, ‘Jun’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘七月’, ‘Jul’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘八月’, ‘Aug’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘九月’, ‘Sep’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘十月’, ‘Oct’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘十一月’, ‘Nov’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘十二月’, ‘Dec’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期日’, ‘Sun’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期一’, ‘Mon’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期二’, ‘Tue’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期三’, ‘Wed’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期四’, ‘Thu’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期五’, ‘Fri’, [rfReplaceAll]);
  Result := StringReplace(Result, ‘星期六’, ‘Sat’, [rfReplaceAll]);
  Result := Result + ‘ GMT’;
end;

Delphi TThread中文注释

TThread是一个抽象类,可以创建几个独立的线程。
类关系 TObject
在一个多线程的应用程序中创建一个TThread的后子类代表一个线程。每一新子类的TThread对象的实例是一个新的线程。从TThread派生的多线程实例可以构成Delphi的多线程应用程序。


   当一个应用程序运行时,应用程序就被载入内存准备执行。此时,它成为包含一个或多个线程的进程,每个线程含有数据、代码和系统资源。线程执行应用程序的部分内容,并由系统分配CPU时间。同一进程的所有线程共享同一地址空间,可以访问进程的全局变量。线程通过以下工作改善应用的性能:管理多通信设备的输入。
   区分任务的优先级。优先级高的处理紧急的任务。优先级低的处理其他任务。
   以下是使用线程的一些建议:
   同时跟踪太多的线程消耗CPU时间。对单处理器系统,一个进程最多有16个线程。
   当多个线程更新相同的资源时,应使线程同步以避免冲突。
   大多数访问VCL对象和更新窗体的方法必须从主VCL线程内部调用。
   以下为创建和使用一个新线程的过程:
   (1)单击File|New|Thread菜单项,创建一个包含对象的新单元,该对象源于TThread类。
   (2)定义新线程对象和Create方法。
   (3)通过插入线程执行时需要的代码定义线程对象和Execute方法。
   (4)将使用VCL组件的任何调用传递给Synchronize方法,以避免多线程冲突。

属性列表
FreeOnTerminate 线程终止时该对象是否自动删除
Handle 包含线程句柄
Priority 确定该线程相对于进程中其他线程的优先级
ReturnValue 返回线程值
Suspended 指示一线程是否被挂起
Terminated 表明线程被要求终止
ThreadID 标识贯穿系统的线程

方法列表
~TThread 删除线程对象并释放其战用的内存空间
DoTerminate 产生一个OnTerminate事件
Execute 提供包含线程执行时所需代码的抽象方法
Resume 重新执行一个挂起的线程
Suspend 挂起一个运行中的线程
Synchronize 在主VCL线程中执行Method
Terminate 将Ternimated属性设置为True通知线程终止
TThread 创建一个线程对象的实例
WaitFor 等待线程终止并返回ReturnValue属性值

事件列表
OnTerminateExecute 方法已返回且该线程被删除前发生

属性

TThread::FreeOnTerminate
__property bool FreeOnTerminate = {read=FFreeOnTerminate,write=FFreeOnTerminate,nodefault};
确定当线程终止时,该线程对象是否自动删除。
FreeOnTerminate默认值为False,线程对象必须在代码中显示删除。
包含线程句柄。
当调用Win32API函数处理线程时,使用Handle.

TThread::Priority
__property TThreadPriority Priority = {read=GetPriority,write=SetPriority,nodefault};
确定该线程相对于进程中其他线程的优先级。
Priority属性为一枚举类型,其默认为tpNormal.
TThreadPriority类型定义了TThread组件的Priority属性的可能值,如下表所述。Windows根据优先级确定每一个线程的CPU周期。
_____________________________________________________________________
    值           含义
_____________________________________________________________________
tpIdle 只有当系统空闲时该线程执行
tpLowest 线程优先级比正常低2点
tpLower 线程优先级比正常低1点
tpNormal 线程优先级为正常值
tpHigher 线程优先级比正常高1点
tpHighest 线程优先级比正常高2点
tpTimeCritical 线程优先级最高

TThread::ReturnValue
__property int ReturnValue = {read=FReturnValue,write=FReturnValue,nodefault};
返回线程值。
使用ReturnValue应用为其他线程指示其成功/失败或数字结果/输出。WaitFor方法返回存储在ReturnValue中的值。

TThread::Suspended
__property bool Suspended = {read=FSuspended,write=SetSuspended,nodefault};
指示一线程是否被挂起。
除非重新执行,否则被挂起的线程不会继续执行。若将Suspended设置为True将挂起一个线程;若设置为False,则继续执行该线程。

TThread::Terminated
__property bool Terminated = {read=FTerminated,nodefault};
表明线程被要求终止。Terminate方法将Terminated属性设置为True。
线程的Execute方法和任何Execute调用的方法将周期性地检查Terminated,当其为True时,将终止执行。

TThread::ThreadID
__property int ThreadID = {read=FhreadID,nodefault};
标识贯穿系统的线程。
当调用Win32API函数处理线程时,ThreadID将十分有用。
注意:ThreadID与Handle属性不同。

方法

TThread::~TThread
__fastcall virvual ~TThread(void);
删除线程对象并释放其战胜的内存空间。
在应用中不要调用~TThread。用delete替代。
~TThread通知线程终止,并在调用Destroy方法前等待该线程返回。

TThread::DoTerminate
virtual void __fastcall DoTerminate(void);
产生一个OnTerminate事件。
DoTerminate调用OnTerminate时间句柄,但并不终止该线程。

TThread::Execute
virtual void __fastcall Execute(void) =0;
提供包含线程执行时所需代码的抽象方法。
Execute查看Terminated属性值以决定该线程是否需要终止。
当CreateSuspended被设置为False,当调用Create时,一线程执行;在线程创建后先调用了Resume且CreateSuspended为True,一线程执行。
注意:不要在线程的Execute方法中直接调用

其他对象的属性和方法。应该将对其他对象的使用分成几个不同的过程,将其作为一个传递到Synchronize方法的参数分别调用。

TThread::Resume
void __fastcall Resume(void);
重新执行一个挂起的线程。
调用Suspend可以嵌套。因此调用Resume必须注意次序。

TThread::Suspend
void __fastcall Suspend(void);
挂起一个运行中的线程。
调用Resume可以继续运行。调用Suspend可以嵌套。因此调用Resume必须次序。

TThread::Synchronize
typedef void __fastcall(__closure* TThreadMethod)(void);
void __fastcall Synchronize (TThreadMethod&Method);
在主VCL线程中执行Method。
Synchronize方法由Method指定的调用被主VCL线程执行。
注意:当在主VCL线程中执行Method时,当前的线程被挂起。

TThread::Terminate
void __fastcall Terminate(void);
通过将Terminated属性设置为True通知线程终止。
线程的Execute方法以及Execute调用的任何方法应周期性的检查Terminated,当其为True时终止运行。

TThread::TThread
__fastcall TThread(bool CreateSuspended);
创建一个线程对象的实例。
在应用中不要直接使用TThread来创建线程。用new替代,传递CreateSuspended参数argument。若CreateSuspended为False,Execute被立即调用。若CreateSuspended为True,Execute直到Resume被调用后才被调用。

TThread::WaitFor
int __fastcall WaitFor(void);
等待线程终止并返回ReturnValue属性值。
直到线程终止时WaitFor才返回,因此线程一定是因为结束了Execute方法或因Terminated属性为了True而终止。如果该线程使用Synchronize,则不要在主VCL线程中调用WaitFor,否则或者引起系统死机,或者产生一个EThread异常。
Synchronize在允许该方法生效前等待主VCL线程进入信息回路。若主VCL线程已经调用了WaitFor,它将不会进入信息回路,Synchronize也永远不会返回。此时,TThread将产生一个EThread意外并使该线程终止;而且如果该意外没有被Execute方法截获,该应用也将终止。如果调用WaitFor时,Synchronize已经在VCL线程中等待,TThread将不会干预,应用程序将死机。

事件

TThread::OnTerminate
__property TNotifyEvent OnTerminate = {read=FOnTerminate,write=FOnTerminate};
当线程的Execute方法已经返回且在该线程被删除之前发生。
OnTerminate事件句柄在主VCL线程被调用。该线程对象也可在该事件中被释放。

Delphi中的线程类

Delphi中有一个线程类TThread是用来实现多线程编程的,这个绝大多数Delphi书藉都有说到,但基本上都是对TThread类的几个成员作一简单介绍,再说明一下Execute的实现和Synchronize的用法就完了。然而这并不是多线程编程的全部,我写此文的目的在于对此作一个补充。
线程本质上是进程中一段并发运行的代码。一个进程至少有一个线程,即所谓的主线程。同时还可以有多个子线程。当一个进程中用到超过一个线程时,就是所谓的“多线程”。
那么这个所谓的“一段代码”是如何定义的呢?其实就是一个函数或过程(对Delphi而言)。
如果用Windows API来创建线程的话,是通过一个叫做CreateThread的API函数来实现的,它的定义为:


HANDLE CreateThread(
LPSECURITY_ATTRIBUTES lpThreadAttributes,
DWORD dwStackSize,
LPTHREAD_START_ROUTINE lpStartAddress,
LPVOID lpParameter,
DWORD dwCreationFlags,
LPDWORD lpThreadId
);

其各参数如它们的名称所说,分别是:线程属性(用于在NT下进行线程的安全属性设置,在9X下无效),堆栈大小,起始地址,参数,创建标志(用于设置线程创建时的状态),线程ID,最后返回线程Handle。其中的起始地址就是线程函数的入口,直至线程函数结束,线程也就结束了。
整个线程的执行过程如下图所示:

因为CreateThread参数很多,而且是Windows的API,所以在C Runtime Library里提供了一个通用的线程函数(理论上可以在任何支持线程的OS中使用):
unsigned long _beginthread(void (_USERENTRY *__start)(void *), unsigned __stksize, void *__arg);

Delphi也提供了一个相同功能的类似函数:
function BeginThread(SecurityAttributes: Pointer; StackSize: LongWord; ThreadFunc: TThreadFunc; Parameter: Pointer; CreationFlags: LongWord; var ThreadId: LongWord): Integer;

这三个函数的功能是基本相同的,它们都是将线程函数中的代码放到一个独立的线程中执行。线程函数与一般函数的最大不同在于,线程函数一启动,这三个线程启动函数就返回了,主线程继续向下执行,而线程函数在一个独立的线程中执行,它要执行多久,什么时候返回,主线程是不管也不知道的。
正常情况下,线程函数返回后,线程就终止了。但也有其它方式:

Windows API:
VOID ExitThread( DWORD dwExitCode );
C Runtime Library:
void _endthread(void);
Delphi Runtime Library:
procedure EndThread(ExitCode: Integer);

为了记录一些必要的线程数据(状态/属性等),OS会为线程创建一个内部Object,如在Windows中那个Handle便是这个内部Object的Handle,所以在线程结束的时候还应该释放这个Object。

虽然说用API或RTL(Runtime Library)已经可以很方便地进行多线程编程了,但是还是需要进行较多的细节处理,为此Delphi在Classes单元中对线程作了一个较好的封装,这就是VCL的线程类:TThread
使用这个类也很简单,大多数的Delphi书籍都有说,基本用法是:先从TThread派生一个自己的线程类(因为TThread是一个抽象类,不能生成实例),然后是Override抽象方法:Execute(这就是线程函数,也就是在线程中执行的代码部分),如果需要用到可视VCL对象,还需要通过Synchronize过程进行。关于之方面的具体细节,这里不再赘述,请参考相关书籍。
本文接下来要讨论的是TThread类是如何对线程进行封装的,也就是深入研究一下TThread类的实现。因为只是真正地了解了它,才更好地使用它。
下面是DELPHI7中TThread类的声明(本文只讨论在Windows平台下的实现,所以去掉了所有有关Linux平台部分的代码):

TThread = class

private
FHandle: THandle;
FThreadID: THandle;
FCreateSuspended: Boolean;
FTerminated: Boolean;
FSuspended: Boolean;
FFreeOnTerminate: Boolean;
FFinished: Boolean;
FReturnValue: Integer;
FOnTerminate: TNotifyEvent;
FSynchronize: TSynchronizeRecord;
FFatalException: TObject;
procedure CallOnTerminate;
class procedure Synchronize(ASyncRec: PSynchronizeRecord); overload;
function GetPriority: TThreadPriority;
procedure SetPriority(Value: TThreadPriority);
procedure SetSuspended(Value: Boolean);

protected
procedure CheckThreadError(ErrCode: Integer); overload;
procedure CheckThreadError(Success: Boolean); overload;
procedure DoTerminate; virtual;
procedure Execute; virtual; abstract;
procedure Synchronize(Method: TThreadMethod); overload;
property ReturnValue: Integer read FReturnValue write FReturnValue;
property Terminated: Boolean read FTerminated;

public
constructor Create(CreateSuspended: Boolean);
destructor Destroy; override;
procedure AfterConstruction; override;
procedure Resume;
procedure Suspend;
procedure Terminate;
function WaitFor: LongWord;
class procedure Synchronize(AThread: TThread; AMethod: TThreadMethod); overload;
class procedure StaticSynchronize(AThread: TThread; AMethod: TThreadMethod);
property FatalException: TObject read FFatalException;
property FreeOnTerminate: Boolean read FFreeOnTerminate write FFreeOnTerminate;
property Handle: THandle read FHandle;
property Priority: TThreadPriority read GetPriority write SetPriority;
property Suspended: Boolean read FSuspended write SetSuspended;
property ThreadID: THandle read FThreadID;
property OnTerminate: TNotifyEvent read FOnTerminate write FOnTerminate;
end;

TThread类在Delphi的RTL里算是比较简单的类,类成员也不多,类属性都很简单明白,本文将只对几个比较重要的类成员方法和唯一的事件:OnTerminate作详细分析。
首先就是构造函数:

constructor TThread.Create(CreateSuspended: Boolean);
begin
inherited Create;
AddThread;
FSuspended := CreateSuspended;
FCreateSuspended := CreateSuspended;
FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), Create_SUSPENDED, FThreadID);
if FHandle = 0 then
raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(GetLastError)]);

end;

虽然这个构造函数没有多少代码,但却可以算是最重要的一个成员,因为线程就是在这里被创建的。
在通过Inherited调用TObject.Create后,第一句就是调用一个过程:AddThread,其源码如下:

procedure AddThread;
begin
InterlockedIncrement(ThreadCount);
end;

同样有一个对应的RemoveThread:
procedure RemoveThread;
begin
InterlockedDecrement(ThreadCount);
end;

它们的功能很简单,就是通过增减一个全局变量来统计进程中的线程数。只是这里用于增减变量的并不是常用的Inc/Dec过程,而是用了InterlockedIncrement/InterlockedDecrement这一对过程,它们实现的功能完全一样,都是对变量加一或减一。但它们有一个最大的区别,那就是InterlockedIncrement/InterlockedDecrement是线程安全的。即它们在多线程下能保证执行结果正确,而Inc/Dec不能。或者按操作系统理论中的术语来说,这是一对“原语”操作。
以加一为例来说明二者实现细节上的不同:
一般来说,对内存数据加一的操作分解以后有三个步骤:
1、从内存中读出数据
2、数据加一
3、存入内存
现在假设在一个两个线程的应用中用Inc进行加一操作可能出现的一种情况:
1、线程A从内存中读出数据(假设为3)
2、线程B从内存中读出数据(也是3)
3、线程A对数据加一(现在是4)
4、线程B对数据加一(现在也是4)
5、线程A将数据存入内存(现在内存中的数据是4)
6、线程B也将数据存入内存(现在内存中的数据还是4,但两个线程都对它加了一,应该是5才对,所以这里出现了错误的结果)
而用InterlockIncrement过程则没有这个问题,因为所谓“原语”是一种不可中断的操作,即操作系统能保证在一个“原语”执行完毕前不会进行线程切换。所以在上面那个例子中,只有当线程A执行完将数据存入内存后,线程B才可以开始从中取数并进行加一操作,这样就保证了即使是在多线程情况下,结果也一定会是正确的。
前面那个例子也说明一种“线程访问冲突”的情况,这也就是为什么线程之间需要“同步”(Synchronize),关于这个,在后面说到同步时还会再详细讨论。
说到同步,有一个题外话:加拿大滑铁卢大学的教授李明曾就Synchronize一词在“线程同步”中被译作“同步”提出过异议,个人认为他说的其实很有道理。在中文中“同步”的意思是“同时发生”,而“线程同步”目的就是避免这种“同时发生”的事情。而在英文中,Synchronize的意思有两个:一个是传统意义上的同步(To occur at the same time),另一个是“协调一致”(To operate in unison)。在“线程同步”中的Synchronize一词应该是指后面一种意思,即“保证多个线程在访问同一数据时,保持协调一致,避免出错”。不过像这样译得不准的词在IT业还有很多,既然已经是约定俗成了,本文也将继续沿用,只是在这里说明一下,因为软件开发是一项细致的工作,该弄清楚的,绝不能含糊。
扯远了,回到TThread的构造函数上,接下来最重要就是这句了:

FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), Create_SUSPENDED, FThreadID);

这里就用到了前面说到的Delphi RTL函数BeginThread,它有很多参数,关键的是第三、四两个参数。第三个参数就是前面说到的线程函数,即在线程中执行的代码部分。第四个参数则是传递给线程函数的参数,在这里就是创建的线程对象(即Self)。其它的参数中,第五个是用于设置线程在创建后即挂起,不立即执行(启动线程的工作是在AfterConstruction中根据CreateSuspended标志来决定的),第六个是返回线程ID。
现在来看TThread的核心:线程函数ThreadProc。有意思的是这个线程类的核心却不是线程的成员,而是一个全局函数(因为BeginThread过程的参数约定只能用全局函数)。下面是它的代码:

function ThreadProc(Thread: TThread): Integer;
var
FreeThread: Boolean;
begin
try
if not Thread.Terminated then
try
Thread.Execute;
except
Thread.FFatalException := AcquireExceptionObject;
end;
finally
FreeThread := Thread.FFreeOnTerminate;
Result := Thread.FReturnValue;
Thread.DoTerminate;
Thread.FFinished := True;
SignalSyncEvent;
if FreeThread then Thread.Free;
EndThread(Result);
end;
end;

虽然也没有多少代码,但却是整个TThread中最重要的部分,因为这段代码是真正在线程中执行的代码。下面对代码作逐行说明:
首先判断线程类的Terminated标志,如果未被标志为终止,则调用线程类的Execute方法执行线程代码,因为TThread是抽象类,Execute方法是抽象方法,所以本质上是执行派生类中的Execute代码。
所以说,Execute就是线程类中的线程函数,所有在Execute中的代码都需要当作线程代码来考虑,如防止访问冲突等。
如果Execute发生异常,则通过AcquireExceptionObject取得异常对象,并存入线程类的FFatalException成员中。
最后是线程结束前做的一些收尾工作。局部变量FreeThread记录了线程类的FreeOnTerminated属性的设置,然后将线程返回值设置为线程类的返回值属性的值。然后执行线程类的DoTerminate方法。
DoTerminate方法的代码如下:

procedure TThread.DoTerminate;
begin
if Assigned(FOnTerminate) then Synchronize(CallOnTerminate);
end;

很简单,就是通过Synchronize来调用CallOnTerminate方法,而CallOnTerminate方法的代码如下,就是简单地调用OnTerminate事件:

procedure TThread.CallOnTerminate;
begin
if Assigned(FOnTerminate) then FOnTerminate(Self);
end;

因为OnTerminate事件是在Synchronize中执行的,所以本质上它并不是线程代码,而是主线程代码(具体见后面对Synchronize的分析)。
执行完OnTerminate后,将线程类的FFinished标志设置为True。
接下来执行SignalSyncEvent过程,其代码如下:

procedure SignalSyncEvent;
begin
SetEvent(SyncEvent);
end;

也很简单,就是设置一下一个全局Event:SyncEvent,关于Event的使用,本文将在后文详述,而SyncEvent的用途将在WaitFor过程中说明。
然后根据FreeThread中保存的FreeOnTerminate设置决定是否释放线程类,在线程类释放时,还有一些些操作,详见接下来的析构函数实现。
最后调用EndThread结束线程,返回线程返回值。
至此,线程完全结束。
说完构造函数,再来看析构函数:

destructor TThread.Destroy;
begin
if (FThreadID <> 0) and not FFinished then
begin
Terminate;
if FCreateSuspended then
Resume;
WaitFor;
end;
if FHandle <> 0 then CloseHandle(FHandle);
inherited Destroy;
FFatalException.Free;
RemoveThread;
end;

在线程对象被释放前,首先要检查线程是否还在执行中,如果线程还在执行中(线程ID不为0,并且线程结束标志未设置),则调用Terminate过程结束线程。Terminate过程只是简单地设置线程类的Terminated标志,如下面的代码:

procedure TThread.Terminate;
begin
FTerminated := True;
end;

所以线程仍然必须继续执行到正常结束后才行,而不是立即终止线程,这一点要注意。
在这里说一点题外话:很多人都问过我,如何才能“立即”终止线程(当然是指用TThread创建的线程)。结果当然是不行!终止线程的唯一办法就是让Execute方法执行完毕,所以一般来说,要让你的线程能够尽快终止,必须在Execute方法中在较短的时间内不断地检查Terminated标志,以便能及时地退出。这是设计线程代码的一个很重要的原则!
当然如果你一定要能“立即”退出线程,那么TThread类不是一个好的选择,因为如果用API强制终止线程的话,最终会导致TThread线程对象不能被正确释放,在对象析构时出现Access Violation。这种情况你只能用API或RTL函数来创建线程。
如果线程处于启动挂起状态,则将线程转入运行状态,然后调用WaitFor进行等待,其功能就是等待到线程结束后才继续向下执行。关于WaitFor的实现,将放到后面说明。
线程结束后,关闭线程Handle(正常线程创建的情况下Handle都是存在的),释放操作系统创建的线程对象。
然后调用TObject.Destroy释放本对象,并释放已经捕获的异常对象,最后调用RemoveThread减小进程的线程数。
其它关于Suspend/Resume及线程优先级设置等方面,不是本文的重点,不再赘述。下面要讨论的是本文的另两个重点:Synchronize和WaitFor。
但是在介绍这两个函数之前,需要先介绍另外两个线程同步技术:事件和临界区。
事件(Event)与Delphi中的事件有所不同。从本质上说,Event其实相当于一个全局的布尔变量。它有两个赋值操作:Set和Reset,相当于把它设置为True或False。而检查它的值是通过WaitFor操作进行。对应在Windows平台上,是三个API函数:SetEvent、ResetEvent、WaitForSingleObject(实现WaitFor功能的API还有几个,这是最简单的一个)。
这三个都是原语,所以Event可以实现一般布尔变量不能实现的在多线程中的应用。Set和Reset的功能前面已经说过了,现在来说一下WaitFor的功能:
WaitFor的功能是检查Event的状态是否是Set状态(相当于True),如果是则立即返回,如果不是,则等待它变为Set状态,在等待期间,调用WaitFor的线程处于挂起状态。另外WaitFor有一个参数用于超时设置,如果此参数为0,则不等待,立即返回Event的状态,如果是INFINITE则无限等待,直到Set状态发生,若是一个有限的数值,则等待相应的毫秒数后返回Event的状态。
当Event从Reset状态向Set状态转换时,唤醒其它由于WaitFor这个Event而挂起的线程,这就是它为什么叫Event的原因。所谓“事件”就是指“状态的转换”。通过Event可以在线程间传递这种“状态转换”信息。
当然用一个受保护(见下面的临界区介绍)的布尔变量也能实现类似的功能,只要用一个循环检查此布尔值的代码来代替WaitFor即可。从功能上说完全没有问题,但实际使用中就会发现,这样的等待会占用大量的CPU资源,降低系统性能,影响到别的线程的执行速度,所以是不经济的,有的时候甚至可能会有问题。所以不建议这样用。
临界区(CriticalSection)则是一项共享数据访问保护的技术。它其实也是相当于一个全局的布尔变量。但对它的操作有所不同,它只有两个操作:Enter和Leave,同样可以把它的两个状态当作True和False,分别表示现在是否处于临界区中。这两个操作也是原语,所以它可以用于在多线程应用中保护共享数据,防止访问冲突。
用临界区保护共享数据的方法很简单:在每次要访问共享数据之前调用Enter设置进入临界区标志,然后再操作数据,最后调用Leave离开临界区。它的保护原理是这样的:当一个线程进入临界区后,如果此时另一个线程也要访问这个数据,则它会在调用Enter时,发现已经有线程进入临界区,然后此线程就会被挂起,等待当前在临界区的线程调用Leave离开临界区,当另一个线程完成操作,调用Leave离开后,此线程就会被唤醒,并设置临界区标志,开始操作数据,这样就防止了访问冲突。
以前面那个InterlockedIncrement为例,我们用CriticalSection(Windows API)来实现它:

Var
InterlockedCrit : TRTLCriticalSection;
Procedure InterlockedIncrement( var aValue : Integer );
Begin
EnterCriticalSection( InterlockedCrit );
Inc( aValue );
LeaveCriticalSection( InterlockedCrit );
End;

现在再来看前面那个例子:
1.线程A进入临界区(假设数据为3)
2.线程B进入临界区,因为A已经在临界区中,所以B被挂起
3.线程A对数据加一(现在是4)
4.线程A离开临界区,唤醒线程B(现在内存中的数据是4)
5.线程B被唤醒,对数据加一(现在就是5了)
6.线程B离开临界区,现在的数据就是正确的了。
临界区就是这样保护共享数据的访问。
关于临界区的使用,有一点要注意:即数据访问时的异常情况处理。因为如果在数据操作时发生异常,将导致Leave操作没有被执行,结果将使本应被唤醒的线程未被唤醒,可能造成程序的没有响应。所以一般来说,如下面这样使用临界区才是正确的做法:

EnterCriticalSection
Try
// 操作临界区数据
Finally
LeaveCriticalSection
End;

最后要说明的是,Event和CriticalSection都是操作系统资源,使用前都需要创建,使用完后也同样需要释放。如TThread类用到的一个全局Event:SyncEvent和全局CriticalSection:TheadLock,都是在InitThreadSynchronization和DoneThreadSynchronization中进行创建和释放的,而它们则是在Classes单元的Initialization和Finalization中被调用的。
由于在TThread中都是用API来操作Event和CriticalSection的,所以前面都是以API为例,其实Delphi已经提供了对它们的封装,在SyncObjs单元中,分别是TEvent类和TCriticalSection类。用法也与前面用API的方法相差无几。因为TEvent的构造函数参数过多,为了简单起见,Delphi还提供了一个用默认参数初始化的Event类:TSimpleEvent。
顺便再介绍一下另一个用于线程同步的类:TMultiReadExclusiveWriteSynchronizer,它是在SysUtils单元中定义的。据我所知,这是Delphi RTL中定义的最长的一个类名,还好它有一个短的别名:TMREWSync。至于它的用处,我想光看名字就可以知道了,我也就不多说了。
有了前面对Event和CriticalSection的准备知识,可以正式开始讨论Synchronize和WaitFor了。
我们知道,Synchronize是通过将部分代码放到主线程中执行来实现线程同步的,因为在一个进程中,只有一个主线程。先来看看Synchronize的实现:

procedure TThread.Synchronize(Method: TThreadMethod);
begin
FSynchronize.FThread := Self;
FSynchronize.FSynchronizeException := nil;
FSynchronize.FMethod := Method;
Synchronize(@FSynchronize);
end;

其中FSynchronize是一个记录类型:
PSynchronizeRecord = ^TSynchronizeRecord;
TSynchronizeRecord = record
FThread: TObject;
FMethod: TThreadMethod;
FSynchronizeException: TObject;
end;

用于进行线程和主线程之间进行数据交换,包括传入线程类对象,同步方法及发生的异常。
在Synchronize中调用了它的一个重载版本,而且这个重载版本比较特别,它是一个“类方法”。所谓类方法,是一种特殊的类成员方法,它的调用并不需要创建类实例,而是像构造函数那样,通过类名调用。之所以会用类方法来实现它,是因为为了可以在线程对象没有创建时也能调用它。不过实际中是用它的另一个重载版本(也是类方法)和另一个类方法StaticSynchronize。下面是这个Synchronize的代码:

class procedure TThread.Synchronize(ASyncRec: PSynchronizeRecord);
var
SyncProc: TSyncProc;
begin
if GetCurrentThreadID = MainThreadID then
ASyncRec.FMethod
else
begin
SyncProc.Signal := CreateEvent(nil, True, False, nil);
try
EnterCriticalSection(ThreadLock);
try
if SyncList = nil then
SyncList := TList.Create;
SyncProc.SyncRec := ASyncRec;
SyncList.Add(@SyncProc);
SignalSyncEvent;
if Assigned(WakeMainThread) then
WakeMainThread(SyncProc.SyncRec.FThread);
LeaveCriticalSection(ThreadLock);
try
WaitForSingleObject(SyncProc.Signal, INFINITE);
finally
EnterCriticalSection(ThreadLock);
end;
finally
LeaveCriticalSection(ThreadLock);
end;
finally
CloseHandle(SyncProc.Signal);
end;
if Assigned(ASyncRec.FSynchronizeException) then raise ASyncRec.FSynchronizeException;
end;
end;

这段代码略多一些,不过也不算太复杂。
首先是判断当前线程是否是主线程,如果是,则简单地执行同步方法后返回。
如果不是主线程,则准备开始同步过程。
通过局部变量SyncProc记录线程交换数据(参数)和一个Event Handle,其记录结构如下:

TSyncProc = record
SyncRec: PSynchronizeRecord;
Signal: THandle;
end;

然后创建一个Event,接着进入临界区(通过全局变量ThreadLock进行,因为同时只能有一个线程进入Synchronize状态,所以可以用全局变量记录),然后就是把这个记录数据存入SyncList这个列表中(如果这个列表不存在的话,则创建它)。可见ThreadLock这个临界区就是为了保护对SyncList的访问,这一点在后面介绍CheckSynchronize时会再次看到。
再接下就是调用SignalSyncEvent,其代码在前面介绍TThread的构造函数时已经介绍过了,它的功能就是简单地将SyncEvent作一个Set的操作。关于这个SyncEvent的用途,将在后面介绍WaitFor时再详述。
接下来就是最主要的部分了:调用WakeMainThread事件进行同步操作。WakeMainThread是一个TNotifyEvent类型的全局事件。这里之所以要用事件进行处理,是因为Synchronize方法本质上是通过消息,将需要同步的过程放到主线程中执行,如果在一些没有消息循环的应用中(如Console或DLL)是无法使用的,所以要使用这个事件进行处理。
而响应这个事件的是Application对象,下面两个方法分别用于设置和清空WakeMainThread事件的响应(来自Forms单元):

procedure TApplication.HookSynchronizeWakeup;
begin
Classes.WakeMainThread := WakeMainThread;
end;

procedure TApplication.UnhookSynchronizeWakeup;
begin
Classes.WakeMainThread := nil;
end;

上面两个方法分别是在TApplication类的构造函数和析构函数中被调用。
这就是在Application对象中WakeMainThread事件响应的代码,消息就是在这里被发出的,它利用了一个空消息来实现:

procedure TApplication.WakeMainThread(Sender: TObject);
begin
PostMessage(Handle, WM_NULL, 0, 0);
end;

而这个消息的响应也是在Application对象中,见下面的代码(删除无关的部分):
procedure TApplication.WndProc(var Message: TMessage);

begin
try

with Message do
case Msg of

WM_NULL:
CheckSynchronize;

except
HandleException(Self);
end;
end;
其中的CheckSynchronize也是定义在Classes单元中的,由于它比较复杂,暂时不详细说明,只要知道它是具体处理Synchronize功能的部分就好,现在继续分析Synchronize的代码。
在执行完WakeMainThread事件后,就退出临界区,然后调用WaitForSingleObject开始等待在进入临界区前创建的那个Event。这个Event的功能是等待这个同步方法的执行结束,关于这点,在后面分析CheckSynchronize时会再说明。
注意在WaitForSingleObject之后又重新进入临界区,但没有做任何事就退出了,似乎没有意义,但这是必须的!
因为临界区的Enter和Leave必须严格的一一对应。那么是否可以改成这样呢:

if Assigned(WakeMainThread) then
WakeMainThread(SyncProc.SyncRec.FThread);
WaitForSingleObject(SyncProc.Signal, INFINITE);
finally
LeaveCriticalSection(ThreadLock);
end;

上面的代码和原来的代码最大的区别在于把WaitForSingleObject也纳入临界区的限制中了。看上去没什么影响,还使代码大大简化了,但真的可以吗?
事实上是不行!
因为我们知道,在Enter临界区后,如果别的线程要再进入,则会被挂起。而WaitFor方法则会挂起当前线程,直到等待别的线程SetEvent后才会被唤醒。如果改成上面那样的代码的话,如果那个SetEvent的线程也需要进入临界区的话,死锁(Deadlock)就发生了(关于死锁的理论,请自行参考操作系统原理方面的资料)。
死锁是线程同步中最需要注意的方面之一!
最后释放开始时创建的Event,如果被同步的方法返回异常的话,还会在这里再次抛出异常。
回到前面CheckSynchronize,见下面的代码:

function CheckSynchronize(Timeout: Integer = 0): Boolean;
var
SyncProc: PSyncProc;
LocalSyncList: TList;
begin
if GetCurrentThreadID <> MainThreadID then
raise EThread.CreateResFmt(@SCheckSynchronizeError, [GetCurrentThreadID]);
if Timeout > 0 then
WaitForSyncEvent(Timeout)
else
ResetSyncEvent;
LocalSyncList := nil;
EnterCriticalSection(ThreadLock);
try
Integer(LocalSyncList) := InterlockedExchange(Integer(SyncList), Integer(LocalSyncList));
try
Result := (LocalSyncList <> nil) and (LocalSyncList.Count > 0);
if Result then
begin
while LocalSyncList.Count > 0 do
begin
SyncProc := LocalSyncList[0];
LocalSyncList.Delete(0);
LeaveCriticalSection(ThreadLock);
try
try
SyncProc.SyncRec.FMethod;
except
SyncProc.SyncRec.FSynchronizeException := AcquireExceptionObject;
end;
finally
EnterCriticalSection(ThreadLock);
end;
SetEvent(SyncProc.signal);
end;
end;
finally
LocalSyncList.Free;
end;
finally
LeaveCriticalSection(ThreadLock);
end;
end;

首先,这个方法必须在主线程中被调用(如前面通过消息传递到主线程),否则就抛出异常。
接下来调用ResetSyncEvent(它与前面SetSyncEvent对应的,之所以不考虑WaitForSyncEvent的情况,是因为只有在Linux版下才会调用带参数的CheckSynchronize,Windows版下都是调用默认参数0的CheckSynchronize)。
现在可以看出SyncList的用途了:它是用于记录所有未被执行的同步方法的。因为主线程只有一个,而子线程可能有很多个,当多个子线程同时调用同步方法时,主线程可能一时无法处理,所以需要一个列表来记录它们。
在这里用一个局部变量LocalSyncList来交换SyncList,这里用的也是一个原语:InterlockedExchange。同样,这里也是用临界区将对SyncList的访问保护起来。
只要LocalSyncList不为空,则通过一个循环来依次处理累积的所有同步方法调用。最后把处理完的LocalSyncList释放掉,退出临界区。
再来看对同步方法的处理:首先是从列表中移出(取出并从列表中删除)第一个同步方法调用数据。然后退出临界区(原因当然也是为了防止死锁)。
接着就是真正的调用同步方法了。
如果同步方法中出现异常,将被捕获后存入同步方法数据记录中。
重新进入临界区后,调用SetEvent通知调用线程,同步方法执行完成了(详见前面Synchronize中的WaitForSingleObject调用)。
至此,整个Synchronize的实现介绍完成。
最后来说一下WaitFor,它的功能就是等待线程执行结束。其代码如下:

function TThread.WaitFor: LongWord;
var
H: array[0..1] of THandle;
WaitResult: Cardinal;
Msg: TMsg;
begin
H[0] := FHandle;
if GetCurrentThreadID = MainThreadID then
begin
WaitResult := 0;
H[1] := SyncEvent;
repeat
{ This prevents a potential deadlock if the background thread
does a SendMessage to the foreground thread }
if WaitResult = WAIT_OBJECT_0 + 2 then
PeekMessage(Msg, 0, 0, 0, PM_NOREMOVE);
WaitResult := MsgWaitForMultipleObjects(2, H, False, 1000, QS_SENDMESSAGE);
CheckThreadError(WaitResult <> WAIT_FAILED);
if WaitResult = WAIT_OBJECT_0 + 1 then
CheckSynchronize;
until WaitResult = WAIT_OBJECT_0;
end else WaitForSingleObject(H[0], INFINITE);
CheckThreadError(GetExitCodeThread(H[0], Result));
end;

如果不是在主线程中执行WaitFor的话,很简单,只要调用WaitForSingleObject等待此线程的Handle为Signaled状态即可。
如果是在主线程中执行WaitFor则比较麻烦。首先要在Handle数组中增加一个SyncEvent,然后循环等待,直到线程结束(即MsgWaitForMultipleObjects返回WAIT_OBJECT_0,详见MSDN中关于此API的说明)。
在循环等待中作如下处理:如果有消息发生,则通过PeekMessage取出此消息(但并不把它从消息循环中移除),然后调用MsgWaitForMultipleObjects来等待线程Handle或SyncEvent出现Signaled状态,同时监听消息(QS_SENDMESSAGE参数,详见MSDN中关于此API的说明)。可以把此API当作一个可以同时等待多个Handle的WaitForSingleObject。如果是SyncEvent被SetEvent(返回WAIT_OBJECT_0 + 1),则调用CheckSynchronize处理同步方法。
为什么在主线程中调用WaitFor必须用MsgWaitForMultipleObjects,而不能用WaitForSingleObject等待线程结束呢?因为防止死锁。由于在线程函数Execute中可能调用Synchronize处理同步方法,而同步方法是在主线程中执行的,如果用WaitForSingleObject等待的话,则主线程在这里被挂起,同步方法无法执行,导致线程也被挂起,于是发生死锁。
而改用WaitForMultipleObjects则没有这个问题。首先,它的第三个参数为False,表示只要线程Handle或SyncEvent中只要有一个Signaled即可使主线程被唤醒,至于加上QS_SENDMESSAGE是因为Synchronize是通过消息传到主线程来的,所以还要防止消息被阻塞。这样,当线程中调用Synchronize时,主线程就会被唤醒并处理同步调用,在调用完成后继续进入挂起等待状态,直到线程结束。
至此,对线程类TThread的分析可以告一个段落了,对前面的分析作一个总结:
1、线程类的线程必须按正常的方式结束,即Execute执行结束,所以在其中的代码中必须在适当的地方加入足够多的对Terminated标志的判断,并及时退出。如果必须要“立即”退出,则不能使用线程类,而要改用API或RTL函数。
2、对可视VCL的访问要放在Synchronize中,通过消息传递到主线程中,由主线程处理。
3、线程共享数据的访问应该用临界区进行保护(当然用Synchronize也行)。
4、线程通信可以采用Event进行(当然也可以用Suspend/Resume)。
5、当在多线程应用中使用多种线程同步方式时,一定要小心防止出现死锁。
6、等待线程结束要用WaitFor方法。

delphi把汉字转换为拼音

function ChineseCharToPinyin(w: WideString): string;
var
vGuid: TGUID;
vFELanguage: IFELanguage;
vError: Integer;
vCaps: DWORD;
vOutput: PMORRSLT;
vPinYin: WideString;
S: WideString;
I: Integer;
iMonoRubyPos: WORD;
iReadIdxWDD: WORD;
vMonoRubyPos: PWORD;
vReadIdxWDD: PWORD;
begin
Result := EmptyStr;
if CLSIDFromString(PWideChar(WideString('MSIME.China')), vGuid) <> S_OK then
    Exit;
vError := CoCreateInstance(vGuid, nil, CLSCTX_SERVER,
    IFELanguage, vFELanguage);
if vError <> S_OK then
    Exit;
vError := vFELanguage.Open;
if vError <> S_OK then
    Exit;
vCaps := 0;
vError := vFELanguage.GetConversionModeCaps(@vCaps);
if vError <> S_OK then
    Exit;
vOutput := nil;
vError := vFELanguage.GetJMorphResult(FELANG_REQ_REV,
    FELANG_CMODE_PINYIN or FELANG_CMODE_NOINVISIBLECHAR,
    Length(W), PWideChar(W), nil, @vOutput);
if vError <> S_OK then
    Exit;
if not Assigned(vOutput) then Exit;
vPinYin := Copy(vOutput^.pwchOutput, 1, vOutput^.cchOutput);
Result := vPinYin;
CoTaskMemFree(vOutput);
vFELanguage.Close;
vFELanguage := nil;
end;

用DELPHI制作在线程序升级信息查询

越来越多的程序支持在线升级功能,本文介绍的就是如何从网站获取升级信息。这里我主要使用版本信息来检测是否需要下载升级版本。
大致原理如下:
   1、放置信息文本到网站。

   2、使用TNMHTTP从网站信息文本获取文本内容。
   3、分析文本解析所需信息。
   4、比较程序版本提供升级信息。
     首先,我们放置一个信息文本到自己的网站,这个文本有自己的文件格式,我定义了如下的格式:
   [update]
     <ver>1.79.9.25</ver>
     <url>http://delphibox.com/softm/3_update.zip</url>
     <date>2002-9-25</date>
   [/update]
我们可以将它保存为update.txt文件,使用[]<>的标示符将信息分类,这里包含了程序名、版本、更新日期和下载地址。这里我假使上传到http://2ccc.com/update.txt。
     然后我们使用TNMHTTP组件从网站获取此文件的内容:
function TForm1.GetUpdateText:String;
begin
   NMHTTP1.InputFileMode := FALSE;
   NMHTTP1.OutputFileMode := FALSE;
   NMHTTP1.ReportLevel := Status_Basic;
   NMHTTP1.Get('http://2ccc.com/update.txt'); { 获取网站文本 }
   Result:=NMHTTP1.Body;
end;
     获取文本以后,我们要将其中的信息分离,我使用了如下的函数:
function TForm1.AnalyseUpdate(Body:String;var Update:TUpdate):Boolean;
var
   TmpStr,Ver:String;
   function CenterStr(Src:String;Before,After:String):String;
   { 这个函数用来分离两个字符串中间的字符串,
     例如 ..('DelphiBox.com','Delphi','.com')=>'Box'。 }
   var
     Pos1,Pos2:WORD;
   begin
     Pos1:=Pos(Before,Src)+Length(Before);
     Pos2:=Pos(After,Src);
     Result:=Copy(Src,Pos1,Pos2-Pos1);
   end;
begin
   TmpStr:=CenterStr(Body,'update'); { 得到程序名间的升级信息 }
   if TmpStr='' then
     Result:=False else { 找不到此文件升级信息 }
   begin
     Ver:=CenterStr(TmpStr,'<ver>','</ver>');
     Update.Version:=SeparateVerStr(Ver); { 解析版本 }
     Update.Date:=StrToDate(CenterStr(TmpStr,'<date>','</date>')); { 解析日期 }
     Update.URL:=CenterStr(TmpStr,'<url>','</url>'); { 解析升级地址 }
     Result:=True;
   end;
end;
其中TUpdate是我定义的信息的记录格式:
   TSimpleVersion=record   { 简化的版本信息 }
     dwProductVersionMS: DWORD; { 主版本 }
     dwProductVersionLS: DWORD; { 辅版本 }
   end;
   TUpdate=record        { 升级信息 }
     Name:String[63];   { 程序名 }
     Version:TSimpleVersion; { 版本 }
     Date:TDate;   { 日期 }
     URL:ShortString;   { 下载地址 }
   end;
而SeparateVerStr()函数是将得到字符串形式的升级版本信息转换为简化的版本信息格式:
function SeparateVerStr(s:String):TSimpleVersion;
const
   Separator='.'; { 以为'.'分割符 }
var
   p,v1,v2,v3,v4:WORD;
begin
   if Length(s)=0 then Exit;
   p:=pos(Separator, s);
   v1:=StrToInt(copy(s,1,p-1));
   Delete(s,1,p);
   p:=Pos(Separator,s);
   v2:=StrToInt(copy(s,1,p-1));
   Delete(s,1,p);
   p:=Pos(Separator,s);
   v3:=StrToInt(copy(s,1,p-1));
   Delete(s,1,p);
   v4:=StrToInt(s);
   Result.dwProductVersionMS:=v1*$10000+v2;
   Result.dwProductVersionLS:=v3*$10000+v4;
end;
     最后要做的就是比较文件的版本信息,先得到自己的版本,我使用如下的函数:
function GetBuildInfo(FName:string):TSimpleVersion; { 得到自身版本信息 }
var
   VerInfoSize: DWORD;
   VerInfo: Pointer;
   VerValueSize: DWORD;
   VerValue: PVSFixedFileInfo;
   Dummy: DWORD;
begin
   VerInfoSize := GetFileVersionInfoSize(PChar(FName), Dummy);
   GetMem(VerInfo, VerInfoSize);
   GetFileVersionInfo(PChar(ParamStr(0)), 0, VerInfoSize, VerInfo);
   VerQueryValue(VerInfo, '\', Pointer(VerValue), VerValueSize);
   with VerValue^ do
   begin
     Result.dwProductVersionMS := dwFileVersionMS; { 主版本 }
     Result.dwProductVersionLS := dwFileVersionLS; { 辅版本 }
   end;
   FreeMem(VerInfo, VerInfoSize);
end;
然后使用如下的函数比较网站的升级版本和现在的版本,如果返回TRUE,说明有新版本文件:
function VersionCheck(OriVer,NewVer:TSimpleVersion):Boolean;
begin
   if (OriVer.dwProductVersionMS=NewVer.dwProductVersionMS) then
   begin
     Result:=OriVer.dwProductVersionLS<NewVer.dwProductVersionLS;
   end else
   begin
     Result:=OriVer.dwProductVersionMS<NewVer.dwProductVersionMS
   end;
end;
     到这里基本方法就介绍完了,我在DELPHI+WIN2000环境调试通过,这里我没有写出完整的代码,在我的主页我做了演示程序,大家可以下载慢慢研究。